
[[2,1,1,1,2,3,3,4,2,4,6,7,11,12,13,5,8,15,9,10][3,5,6,8,6,5,8,7,10,9,12,11,15,15,14,13,14,19,16,17][4,9,7,10,16,11,12,17,19,20,13,14,16,17,18,19,20,20,18,18]]\T\\->\[D]
Lbl 0
seq(0,I,1,20\->\\L\D
1\->\\L\D(randInt(2,10
1\->\\L\D(randInt(11,20
2\->\\L\D(randInt(2,10
2\->\\L\D(randInt(11,20
randInt(11,20\->\W
Lbl 1
ClrHome
1\->\P:3\->\A
While 1
  If P=W:Then
    Disp "BUMPED A WUMPUS!
    If 4rand<1:Then
      Disp "HA HA-- THE","WUMPUS GOT YOU!
      Goto D
    End
    [D](W,randInt(1,3\->\W
  End
  If 2=\L\D(P:Then
    Disp "FLAP FLAP...
    Repeat Ans\!=\W and 2\!=\\L\D(Ans
      randInt(1,20\->\P
    End
  End
  If 1=\L\D(P:Then
    Disp "YIIEE!... YOU","FELL IN A PIT!
    Goto D
  End
  " 
  Disp Ans,Ans,Ans,Ans,Ans,Ans,Ans
  Output(1,1,"ROOM
  DelVar BDelVar TDelVar QOutput(1,6,P
  For(I,1,3
    [D](P,I\->\D
    T or 1=\L\D(Ans\->\T
    B or 2=\L\D(D\->\B
    Q or W=D or max(seq(W=[D](D,M),M,1,3\->\Q
  End
  If T:Output(2,2,"I FEEL A DRAFT.
  If B:Output(3,2,"I HEAR BATS.
  If Q:Output(4,2,"WUMPUS NEARBY!
  Output(5,1,"TUNNELS LEAD TO
  Output(6,1,seq([D](P,B),B,1,3
  DelVar MOutput(7,1,"MOVE (S-M):
  Repeat Ans=105 and M
    Repeat Ans:getKey:End
    If Ans=65:1\->\M
    If Ans=81:2\->\M
    Output(7,13,sub("?MS",1+M,1
  End
  If 1=M:Then
    Input "MOVE TO: ",M
    If max(seq(M=[D](P,B),B,1,3:Then
      M\->\P
    Else
      Disp "INVALID MOVE
    End
  Else
    "NO
    If A:Then
      Input "SHOOT THRU: ",Str1
      "{"+Str1\->\S:\L\S
      If 5<dim(Ans:Then
        Disp "TOO FAR.
        sub("12",A,1
      Else
        P\->\M
        For(I,1,dim(\L\S
          If max(seq(\L\S(I)=[D](M,B),B,1,3
          Then
            \L\S(I\->\M
          Else
            Disp "IT RICOCHETS!
            [D](M,randInt(1,3\->\M
          End
          If M=P:Goto D
          If M=W:Goto W
        End
        If 4rand>1:[D](W,randInt(1,3\->\W
        "NO
        DS<(A,1
        sub("12",A,1
      End
    End
    Disp "YOU HAVE "+Ans+" MORE
    "S.
    If A=1:".
    Pause "ARROW"+Ans
  End
End

Lbl D
Disp "YOU LOSE!
Output(8,1,"SAME SETUP?
DelVar MRepeat M and Ans=105
  Repeat Ans:getKey:End
  If Ans=92:1\->\M
  If Ans=71:2\->\M
  If Ans=74:3\->\M
  Output(8,13,sub("?YNQ",1+M,1
End
If 1=M:Goto 1
If 2=M:Goto 0
Disp "
Return
Lbl W
DelVar [D]DelVar \L\DDelVar \L\SDisp "YOU SHOT THE","WUMPUS!

