
  prgmZSRL is a fast screen-scroller utility. It expects Str9 to be
initialized to " : : : : : :", or any string containing six colons
not next to each other, and Str8 to be full of spaces (used only to
erase the ends of lines during scrolling).
  Put the string you want to add to the screen display into Ans,
and invoke prgmZSRL. It will add that string to the end of the screen
display, wrapping lines as needed, and then re-display the whole
screen. If you want to add your own linebreaks instead of relying
on prgmZSRL's algorithm, use a colon ":" to represent a linebreak.
  Important note: Each colon must have at least one character after
it! To print a blank line, use the string " ", not ":" or "". To
print two blank lines, use " : ", not " :" or ": ".

  prgmZSRL will overwrite variables A, B, C, and Ans. It won't touch
any other variables.

  I release this utility program into the public domain; please use
it, modify it, do whatever you want with it, if it will help you
produce quality programs. If you find a way to make prgmZSRL faster,
please let me know, so I can update Castle Adventure.


For(A,length(Ans),0:End
Str9+Ans+":\->\Str9
length(Ans\->\B
DelVar CFor(A,B-A,B
  1+C\->\C
  inString(Str9,":",A
  If A+23\>=\Ans:Then
    Ans\->\A
  Else
    A+23
    While " "\!=\sub(Str9,Ans,1:Ans-1:End
    Ans\->\A
    sub(Str9,1,Ans-1)+":"+sub(Str9,Ans+1,B-Ans\->\Str9
    A
  End
End

1\->\A
For(C,Ans,C
  1+inString(Str9,":",Ans
End
sub(Str9,Ans,1+B-Ans\->\Str9
For(C,2,7
  inString(Str9,":",A
  Text(7C,3,sub(Str9,A,Ans-A),Str8
  Ans+1\->\A
End
